コマンド拡張で学ぶVZマクロ入門 #58

s==0(編集モード)

対応する括弧の検索

戻り値 r：常に 0

()[]{}<>のいずれかにカーソルがあるとき，対応する括弧にカーソルを移動する。ファイル拡張子が .h .c の場合，カーソル位置の文字にかかわらず '}' 上にあるものとしてブロックの開始に移動する。

s==1(文字列入力モード)

無効

s==2(コマンドラインモード)

無効

s==3(ファイラーモード)

無効

s==4(メニュー)

• メニューのキャンセル
• メニューの戻り値として以下の値をrにセットする

戻り値rの内容

• 下位7ビット：コマンド番号58==$3A
• 上位9ビット：フラグやカーソル位置
  • 最上位ビット：特殊キー入力フラグ
  • 次の7ビット：カーソル位置
  • 次の1ビット：コマンド／マクロキーフラグ
  • リードオンリーメニューでは上位オクテットに$FF

s==4(1文字入力モード)

無効

マクロによる擬似的な拡張

なんでも拡張すればよいというものではないサンプルである。一応，大真面目に作ったものであったが，使う場面が一切ないのだ。

= blanket.def = by H_ear
対応する全角括弧の検索（要vwx）
* mad for vz!
1 ^^ "" ?. &s &#M(3)
        mp[, n+,
        &> &SF(a,cd) c=r, r-=a,
        b=(r/2)&1,      ;back
        #F      ; 開き括弧(vr1)|閉じ括弧(vr2) の順
        (b)?{ &?("\x %2s|%2s",c-2,c) }
           ?{ &?("\x %2s|%2s",c,c+2) } #m
        &02             ;search
:q      (n)?{ &#U(3) &m("見つかりません") }
:z      mp],
        &d #] .
0:      a3+$,."‘’“”（）〔〕［］｛｝〈〉《》「」『』【】"
2:      ;-----  入れ子を数えて対応する括弧を検索
        ; ex. （ ……（ …… ）…… ）
        ;  n+= +1     +1    -1     -1
        &o(#c-b)
        (r)??{
                (b)?{ n-=1-vr&2, }?{ n+=1-vr&2, }
                (n>0)?>^
        }
*