VZトークン関連覚書

マクロ番号割当て規則

公式には以下のようになっている。

グローバルマクロ番号	1〜89
キーボードマクロ番号（自動付与）	90〜99
ローカルマクロ番号	1〜99
メニュー番号	1〜30

実際には以下のようになっている。

グローバルマクロ番号（キーボードマクロ番号帯を含む）	1〜127
ローカルマクロ番号（メニュー番号帯を含む）	0〜126

キーボードマクロの自動付与番号は，90番以降でグローバルマクロの最も大きな番号の次の番号が割り振られる。つまり，グローバルマクロで90番を使っていれば，キーボードマクロは次の91番から振られることになる。仕様はいずれにしても特別な理由のない限り，グローバルマクロの番号は89番までとし，マクロローダ等で使われることの多い87〜89も空けておいた方が無難だ。

また，ローカルマクロ番号も通常は95番までにとどめておくべきである。通常の使い方をする以上，メニュー用の番号は空けておかなければならないからだ。キーボードマクロの場合は自動的に使える番号を振ってくれるが，メニューはそうはいかない。

マクロ＆メニュー番号詳細

区分	番号	内部設定値（十六進数）	割り当てられる要素
マクロ	1〜89	1〜89（01h〜59h）	グローバルマクロ（127まで使用可能）
マクロ	90〜127	90〜127（5Ah〜7Fh）	キーボードマクロ（グローバルマクロが使用可能）
マクロ	0:〜96:	128〜223（80h〜DFh）	ローカルマクロ（126:まで使用可能）
メニュー	0	224（E0h）	ヘルプメニュー（ローカルマクロが使用可能）
メニュー	1〜30	225〜254（E1h〜FEh）	メニュー（ローカルマクロが使用可能）

このように想定された範囲を越えてマクロ番号は割当て可能である。しかし，>100 &100 のように3桁の番号を指定してジャンプ／コールできるわけでもなく，ただ >> &> が使えるのみでは，わざわざ使うメリットはない。（マクロ，メニューの番号指定の解釈は数字２文字によって行われ，３桁以上に限らず >1 &1 のような１桁も正常に解釈されない。１桁の場合は２桁になるようゼロをパディングして >01 &01 のように記述する。）

ただし，メニューに相当する番号を付与したマクロが実行できるということで，擬似メニューのような技術が開発されるに至ったことを思えば，マクロ達人の探求心はおそるべしと敬愛の念を禁じえないのである。

= test
* m
1 ^\ "test" ?.
        r="test",
        &>
        !30

125:    ; 125までは問題ないが，126はメニューの30と重なるので問題あり
        &m("Result: %d %u $%x '%c' $"%16s$"",r,r,r,r,r)
* p
30 "menu",10,1,,-1 "item"
*

起動キーの割当て規則

定義の方法

マクロ番号とタイトルの間に０個〜２個の起動キーを記述することで定義する。常用でないマクロであれば起動キーを与えず，外部マクロ実行（[ESC]^）機能で組込み・実行したり，組み込んだあとはモジュールメニュー（[ESC]M）から実行するという選択肢もある。

==== macro ====
* m
1 [第１キー] [第２キー] "タイトル"

ひとつのコマンドまたはマクロについての定義規則

• ２個のキーを定義できる
• 特殊キーは１個だけ定義できる
• ３番目以降のプリフィクスキーは１個だけ定義できる（先に記述する必要がある）
• （特殊キーと３番目以降のプリフィクスキーはどちらか１個だけ定義できる）：どこかでこんな記述を見たような気もするがv1.5の話だったかも

用例1　２個のキーのうち１個が特殊キー

24 ^L [F05] "Get Right Words"

× ^[-->] [F05] "Get Right Words"

用例2　３番目以降のプリフィクスキーを先に記述

8  [ESC]I @I "Insert File"

× @I [ESC]I "Insert File"	;起動できない／同じキーの他のマクロが起動される

この理由は，２個目にアサインされるプリフィクスキーの値は7Fhまでしか入れず，80h以上の場合は２番目のキーの値で１番目のメモリを上書きしてしまうためである。

• 特殊キーは常に２個目のキーとしてメモリに格納される
• ３番目以降のプリフィクスキーは常に１個目のキーとしてメモリに格納される
• [Ctrl]+英字と[Alt]+英字はどちらでも格納できる

…といった制限によるものだ。

特殊キーは３番目以降のプリフィクスキーと値が重複しており，次の表のようにメモリに格納される。

キー値	１番目のキー	２番目のキー
00h-7Fh	^A, @A, Pfx1, Pfx2	Pfx1, Pfx2, ^A, @A,
80h-FEh	Pfx3, Pfx4, Pfx5, Pfx6	[Key], \[Key], ^[Key], @[Key]

例えば，[F01] [ESC]A のように２個のキーを記述すると，メモリ上では記述順ではなく [ESC]A [F01] の順に格納される。もっとも [ESC]A と [F01] はキーの値が同じなのでメモリダンプしても見分けがつかないであろう。:-)

なお，プリフィクスキーと特殊キーの重複する値の対応表は「コマンド拡張で学ぶVZマクロ入門 #00」に掲載してあるものを参照されたい。

キーストローク

コマンド，マクロの起動キーとして機能キー（CtrlやAlt）とともに押したり，２ストローク（プリフィクス）キーの２打目に押せるキーは，キーボードから直接入力でき，次の文字コードの範囲（40h〜5Fh）に含まれる。

+$0

+$1

+$2

+$3

+$4

+$5

+$6

+$7

+$8

+$9

+$A

+$B

+$C

+$D

+$E

+$F

40h

@

A

B

C

D

E

F

G

H

I

J

K

L

M

N

O

50h

P

Q

R

S

T

U

V

W

X

Y

Z

[

\

]

^

_

プリフィクスキーの直後に押して戻り値を返すキーは，次の文字コードの範囲（30h〜3Fh）に含まれる。

+$0

+$1

+$2

+$3

+$4

+$5

+$6

+$7

+$8

+$9

+$A

+$B

+$C

+$D

+$E

+$F

30h

0

1

2

3

4

5

6

7

8

9

:

;

<

=

>

?

参考：^ @ \ [ ] の別の解釈

^	コマンド	#^
	関数	&^
	フロー制御	>^
	二項演算子	^
	論理演算子	^^
	代入演算子	^=
	ファイルメニューオプション	%^
@	起動時オプション	@, @@
\	DOS:パスの区切り文字	\	fg.33の部品
	エスケープシーケンス（制御文字）	\n, \l, \r, \*, \\
	特殊文字（検索オプション）	\x, \0, \w, \c, \z, \i
	ファイルメニューオプション	%\
[	単項演算子	[
	代入演算子	[=
	コマンド	#[
	文字列内の展開出力	$[n], $[n,c]
]	単項演算子	]
	コマンド	#]
	文字列内の展開出力	$[n], $[n,c]

【$】　実行位置のポインタ

$自身のマクロバッファ内のオフセットアドレスを示す。主な用途は以下のとおり。

自前バッファの確保

        &01 &02
1:      a3+$,."$[80]"           ;通常バッファ
2:      (5+$)."$(50,0)$[80]"    ;履歴バッファ

メニューヘッダのアドレス取得

10:     (9+$).  ;$の次の)から9バイト先がメニュータイトル
* popup menu
1       "0000/00/00(・)",16,7
        "O ?日前後"
        "B   一昨日"

自己書換位置アドレスの取得

1 ^\ "" ?.
        a-,
 :a     b=5+$, &m("・・・・")
        (a%2)?c="おはよう", ?c="おやすみ",
        &Sp(b,"%s",c) &w(60)
        (a++<6)?>a
        .

【$】　特殊文字の意味を打ち消す

文字列中にある特殊文字の意味を打ち消すときに前置する。対象となる特殊文字は である。

【$$】　「$」自身

文字列中に「$」文字そのものを出力する。 特殊文字の意味を打ち消して「$」そのものを文字列中に含ませるための機能である。

正規表現で行末にマッチさせようとするとき，指定文字列の末尾に「$」があることになる。これをこのままにしてしまうと，文字列末尾を示す「"」の特殊文字としての機能が無効になってしまい，後続のマクロコードの部分も延々と文字列が続いているという扱いになってしまう。

用例

×      #F &?("\x ^<h%d[^>]*>.+</h%d>$",h,h) #m
                                     ↓
○      #F &?("\x ^<h%d[^>]*>.+</h%d>$$",h,h) #m

参考

末尾に「$」のある文字列を検索文字列にセットするには

【$"】　「"」そのもの

文字列中に「"」文字そのものを出力する。文字列終端を示す「"」の意味を打ち消して文字列中に含ませるための機能である。

用例

        &m("Press the $"ENTER$" key after verifying that ...")

        → 「Press the "ENTER" key ...」と出力される

参考

「"」を含む文字列を検索文字列にセットするには

【$0〜$7】　表示属性

文字列中で表示色を変更する

0:黒 1:青 2:緑 3:水 4:赤 5:紫 6:黄 7:白
(IBM-PCは低輝度)

用例

        &g("$00:黒 $11:青 $22:緑 $33:水 $44:赤 $55:紫 $66:黄 $77:白")

のように表示する

【$!】　表示属性

文字列中で表示色を反転する（リバース）

用例

        &g("表示を $! 反転 $! する")

のように表示する

【$p?】　展開出力

文字列中で変数p?の示す文字列を展開表示する

用例

テキストウィンドウのタイトルでの実例を示す

* Text windows

"Open File: <$pd> [$wc/$tc]",50
"Search: <OPT:$po> \[wczxif]",50
"Replace: [$ps] to ?",50

pd（カレントディレクトリ名）を表示する例

po（検索オプション文字列）を表示する例

ps（検索文字列）を表示する例

【$a?】　表示属性

文字列中でオプションa?の示す表示色に変更する

用例

&g("abc$andef$aoghi")

入力窓のタイトルに のように表示される（色はAnとAoに依存）

使用可能な表示属性のオプション

An	通常のテキスト
Ac	コントロール文字１
Ae	コントロール文字２(v1.6)
Al	行番号
Ah	ブロック領域
As	ステータスライン
Ao	コンソールファイルのステータスライン
Ar	リードオンリファイルのステータスライン
Am	最下行のメッセージ
Ab	ウィンドウわく
At	ウィンドウタイトル
Aw	ウィンドウメニュー
Af	ウィンドウメニューのダイレクトキー
Ai	ウィンドウメニューのカーソル
Aj	ヘルプウィンドウ
Ak	２ストローク先頭キー
Ag	ファイラーの背景
Au	ファイラーのカーソル
Ap	ファンクションキー（IBM-PC版）
Ad	DOSコマンドライン
Ay	ステータスラインのファイル名(v1.6)
Av	アンダーラインのテキスト属性

【$??】　展開出力

文字列中で変数??の十進表示を展開

用例

        &g("タブ幅は$htカラム")

入力窓の標題に のように編集中テキストのタブ幅が表示される。

【$(hh,hh,..)】　展開出力

文字列中で十六進コードを指定して展開出力

用例

        &g("$(83,5e,83,43,83,67,83,8B)")

入力窓の標題に と表示される

注意

&?("$(0d,0a)")のように記述すること自体は間違いではなく，マクロバッファにも読み込まれるが，改行コードの出力はできない。

【$[n]】　展開出力

文字列中にnバイトのヌル(0)を展開出力する。 自前バッファの簡易設定に利用できる（v1.6）。

用例

自前バッファの設定例を示す

        &>                      ;[a] 変数aにアドレスを取得して戻る
        &01 b=r,                ;[b] 戻ってから変数bにアドレスを取得

        ; ---- buffers ----
0:      a3+$,."$[80]"           ;通常バッファ
1:      (5+$)."$(50,0)$[80]"    ;履歴バッファとしても使える

アドレス指定位置は以下のように数える

0:      a3+$,."$[80]"           ;サイズ情報がない
;           0123
1:      (5+$)."$(50,0)$[80]"    ;サイズ情報は2バイト
;           012  3  4 5

【$[n,c]】　展開出力

文字列中にnバイトの文字cを展開出力する 自前バッファの簡易設定に利用できる（v1.6）

用例

        &m("123$[8,'0']456")
        ;メッセージラインに「12300000000456」と表示される

        &?("{$[2,9]}")
        ;カーソル位置に「{<- TAB -><- TAB ->}」と出力される


0:      (3+$)."$[16,'@']"
        ;自前バッファに「(3+$)."@@@@@@@@@@@@@@@@‥」のように展開される
        ;「‥」はヌル(00h)２個を示すものとする

単項演算子

演算子	用例	機能
[	a[	プッシュ：aの値をマクロスタックに格納してスタックポインタを更新 [変更]
]	a]	ポップ：マクロスタックの値をaに格納してスタックポインタを更新 [変更]
++	a++	aの値を加算（インクリメント）「a=a+1」と等価
--	a--	aの値を減算（デクリメント）「a=a-1」と等価
~	a~	aにaの補数を格納（１の補数、ビット反転）「a=~a」と等価
!	a!	aにaの論理否定値を格納（0以外は1，0は1）「a=!a」と等価
!!	a!!	上位バイトと下位バイトの交換

※以下のものは優先順位が二項演算子と同様に扱われる

演算子	用例	機能
+	a+	a=1と同じ （もともと代入との組合せで「=+」の省略形だが，代入演算子の省略により演算の優先順位が変化している。）
-	a-	a=0と同じ （もともと代入との組合せで「=-」の省略形だが，代入演算子の省略により演算の優先順位が変化している。）
-	-a	符号の反転 a*=-1と同じ

※注意事項

• ポインタで示されるアドレスの値をプッシュする場合のように，より優先順位の低い演算を優先させる場合，開き括弧を前置することでエラーを回避する。あるいはプッシュ後代入を使用する。

  ×	(p..0)[,
  ○	((p..0)[,
  ○	p..0[=0,

• 逆にポインタで示されるアドレスに値をポップする場合，ダミーにポップして代入するという方法がある。

  ×	((p..0)],
  ○	p..0=0],

• 一見ダメに見えそうな「a..0-」は，「a..0=-」の省略形であるため式として通る。単項演算子として使える「+」と「-」は省略された代入演算子との組合せであるため，優先順位が低くなると考えても大嘘ではないかもしれない。

混合式におけるプッシュ・ポップ演算子の振る舞いは，v1.6で変更になっている。

= test by NaruTo (PK14#09098_1994-12-11)
*m
1 ""    ?.
        6[, 4[, 6[, 4[,
        &m("%d %d",0]+0],r]+r])
*

　このマクロを実行すると，v1.57では「10 10」，v1.60では「10 12」を示す。

二項演算子

演算子	用例	機能
..	a..0	ワードポインタ（使用されるセグメントは dz）[変更]
.	a.0	バイトポインタ（使用されるセグメントは dz）[変更]
<<	a<<1	左シフト（ビット単位でずらす）
>>	a>>1	右シフト（ビット単位でずらす）
&	a&b	ビットごとの論理積（AND）
^	a^b	ビットごとの排他的論理和（XOR）
|	a|b	ビットごとの論理和（OR）
*	a*b	乗算
/	a/b	除算（余りは切り捨てられる。戻り値に余りが入ったりしない。）
%	a%b	剰余（a%b は a÷b の余り）
+	a+b	加算
-	a-b	減算

※注意事項

• '..'と'.'はv1.5x以前とv1.6で優先順位が逆転している
• 符号付きのポインタにヌルを埋める時は注意
  　例：pn..(-38).0-, または pn..37~.0-, もしくは pq..137.0-,
• 加算と減算の混合式は特に注意
  　例：1-1+1 は 1-(1+1) で -1 となるので，ループに使うと無限ループや暴走の可能性もある。この例だけなら 1--+1 とも書ける。

論理演算子

演算子	用例	機能
<	a<b	小なり
<=	a<=b	以下
>	a>b	大なり
>=	a>=b	以上
==	a==b	等しい
!=	a!=b	等しくない
&&	a&&b	論理積
^^	a^^b	排他的論理和
||	a||b	論理和

代入演算子

演算子	用例	機能
=	a=b	代入(省略すると前の括弧も省略されているのと同じ扱い)
[=	a[=b	プッシュ後代入（a[,a=b）
&=	a&=b	ビット毎の論理積（AND）を代入
^=	a^=b	ビット毎の排他的論理和（XOR）を代入
|=	a|=b	ビット毎の論理和（OR）を代入
*=	a*=b	積を代入
/=	a/=b	商を代入（余りは切り捨て）
%=	a%=b	剰余の代入（一定範囲の数値に丸める）
+=	a+=b	和を代入
-=	a-=b	差を代入

【:】　次の1文字をラベルにする

識別子【:】に続く1文字をラベルにする。

• 大文字アルファベットに限らず小文字や記号も使用可能
• 行頭に限らずマクロ内のどこでも使用可能
• 文字列の中にあってもラベルとして認識する可能性がある

特に注意すべきことは，メッセージ等の文字列に含まれるコロンの次にラベルになりうる文字があったとき，その位置がラベルと誤認される可能性があることだ。テスト中に変数の値を表示する時などに，「&m("a:b = %d:%d",a,b)」のように書いたとしよう。この文字列中の「:b」はラベルになりうる。本来のラベルの前にこの命令があれば，確実にこの位置にジャンプしてくる。ちなみに「:%」もラベルとなりうる。

文字列中にこのようなラベル様の文字があったとしても，大抵はコードとして意味のない次の文字列に遭遇して停止してしまうし，万一コードとして実行可能な文字列が続いていたとしても文字列終端のヌルで確実に強制終了される。文字列中にコロンを使った場合は，コロンの後に空白を1文字入れておくとよいかもしれない。

また，マクロのどの位置にも配置できるラベルだが，マクロ全体の見通しをよくするためにも，できるだけ行頭付近に記述したほうがよいだろう。

【>】　続く１文字の示すラベルにジャンプ

前項で示したように，ラベルジャンプは単純にマクロバッファ内をスキャンしてゆくので注意が必要だ。あまり神経質になる必要はないがマクロの見通しを良くしておくことが大切だ。

また，マクロ内に飛び先が見つからない場合，同じモジュール内の別のマクロにある同じ名称のラベルに飛んでしまうことがある。ローカルマクロだけでなく，グローバルマクロの垣根を越えて飛んでゆき，戻ってくることはない。この動作を見切った上で敢えて書くという手もあるが，あまり多用しない方がよいだろう。

【.】　実行中のマクロを終了して呼出元に戻る

高級言語で言うところの return である。通常は単純にマクロの停止命令と考えてよい。

&nnでコールされたマクロの実行を終了して呼出元に戻るとき，その時点の内部レジスタの値をシステム変数rに格納する。サブルーチンを (0). として終了すると，あたかも return 0; のように戻り値を抱えて戻ってくるわけだ。つまりマクロであってもサブルーチンできちんと評価を行えば，呼出元できちんと分岐を行える。プログラムの基礎として身に付けたい習慣だ。

なお，.で戻ってきてから呼出元の実行が再開されるのは，コールするときにリターン後に実行を開始する次の命令位置をmg..2..1に記憶させているからである。

【/】　マクロの実行を強制的に中断（呼出元に戻らない）

高級言語で言うところの break …と言いたいところであるが，実際にはもっと邪悪な命令である。何の保存も復帰もしてくれない強制終了命令なのだ。さすがにマクロの実行中断後にエディタとしての機能に大きな問題を生じるようなオプション（mx,ep,ux）や文字列バッファのアドレスなどはリセットされるが，プッシュ・ポップの辻褄が合わなくなったりするので極力使用は避けるべきであろう。

【?】　条件分岐

内部レジスタが偽（0）なら次の命令文／ブロックをスキップする簡易な条件分岐である。

(式)のように括弧で式をくくると，その式を評価して結果を内部レジスタに格納する。条件分岐を成立させている秘密の鍵こそ内部レジスタである。内部レジスタは，市販の解説書ですらコマンド等の戻り値rと混同されているものがあるほど正体の見えにくい存在だが，マクロ関係構造体の mg..0 に格納されているrとは別の値である。条件分岐の際はこの内部レジスタを参照して次の命令文／ブロックの実行を制御している。

機能の裏返しである「真（0以外）なら次の命令文／ブロックを実行」というイメージがあって，通常は次のように記憶されている。

(式1)?{ 式1の評価が真のとき実行 }

例外のない裏返しであるから間違いとは言えないが，注意しなければならないのは，「条件分岐」の説明であたかも次のようなフロー制御を想像してしまうことだ。

(式1)?{ 式1の評価が真のとき実行 }?{ 式1の評価が偽のとき実行 }

この構造を用いて説明することは，あまり正確ではない。むしろ不正確な説明である。通常は，あたかもこのような条件分岐のようにふるまうが，【?】を実行した直後に内部レジスタを論理NOTすることで巧妙に分岐させているのである。

(式1)	式1を評価すると0以外（真）か0（偽）が内部レジスタ（mg..0）に格納される。
?	この時点の内部レジスタの値を参照して，次のブロックの実行の有無を決定し，内部レジスタを論理NOTする。
{ 式1の評価が偽のときスキップ }	式の評価が偽のとき，このブロックはスキップされる。つまり式1の評価が真なら実行される。実行に先立ち内部レジスタの値は0（偽）になっているが，ブロック内で内部レジスタがどのように変化しようとも関知されない。
?	「この時点の」内部レジスタを参照して，次のブロックの実行の有無を決定し，内部レジスタを論理NOTする。直前のブロックで内部レジスタの値に変化がなければ，0（偽）のために次のブロックはスキップされる。そして内部レジスタは論理NOTされて1（真）となっている。
{ 式1の評価にかかわらず直前の内部レジスタが偽のときスキップ }	もしも前のブロックの中で何かしら値が評価されて内部レジスタに0以外の値が格納されていれば，式1の評価が真だった場合でもスキップされずに実行される。

所期の動作（「条件分岐」というイメージから想像されるプログラム言語らしい動作）をさせたい場合は，２番目のブロックの最後で強制的に内部レジスタに0を格納すればよい。具体的には，次のように(0)を加えてやればよい。

(式1)?{
        式1が真の時に実行
        (式2)?{
                式2が真の時に実行
        }
        (0)
}?{
        式1が偽のときに実行
}

内部レジスタの値の変化は次のようになる。

(式1)	式1の評価が真		式1の評価が偽
?	次のブロックを実行 　内部レジスタは0に変化		次のブロックをスキップ 　内部レジスタは1に変化
{ ブロック1	実行		スキップ
(式2)	式2の評価が真	式2の評価が偽
?	次のブロックを実行 　内部レジスタは0に変化	次のブロックをスキップ 　内部レジスタは1に変化
{ ブロック1(2) }	実行	スキップ
(0) }	内部レジスタはダメ押しで0
?	次のブロックをスキップ		次のブロックを実行
{ ブロック2 }	スキップ		実行

【?】を実行する段階での内部レジスタの値によって次のブロックを実行するかどうかが決定されるということが理解できれば，条件分岐の動きを見切った書き方が可能になる。

例えば，(式)と?は連続していなくても構わない。

(式1) 命令[群] ?{ 式の評価が真のとき実行 }

命令[群]において内部レジスタの値が絶対に変化しないのであれば，次のブロックの実行について動作が変わることはない。命令[群]において式1の値が変化したとしても，内部レジスタさえ変化しなければ問題はない。

例えば，式1の評価を左右した値が変わっても構わない。

(r) 戻り値のあるコマンドを実行 ?{ コマンド実行の成否による分岐の変動はない }

(偽)? でスキップされる命令こそトークンである。その解釈について高橋版VZの製作者である高橋洋光氏は次のように解説する。

? に続く文字が「!#(&>{'"」以外だと、'A' より大きければアルファベットで始まる変数名で式，小さければ１文字スキップになります。（dc13#06056,Hiro）

つまり，１文字スキップするのは「$%)*+,-0123456789:;<=?@」である。何？【;】があるのは何故か？自己書換で試してみてほしい。確かに認識されている。

1 ^\ "test" &t
        c13+$, c.0=';',
        (0)??
        &m("%d/%d",a,b)
*

なお，引数のある関数の直前でスキップが発生すると，括弧の手前までがスキップされて括弧部分が独立して実行される。書式制御が含まれる場合は分断されるが，複数の式として解釈されるため，通常は何事もなかったように実行される。ただし，内部レジスタは不定となる。

        (0)?&m("%d/%d",a,b)

このコードがどのように実行されるか確かめてみると，次のようになる。

        (0)　→　?　→　&m　→　("%d/%d",　→　a,　→　b)

引数部分は意図してか偶然か，すべて式として成立するためエラーにはならない。しかし最終的に b) によって b が評価され，内部レジスタの値が変動する。

【{】　ブロック開始・ループのポインタとカウンタのセット

ブロックの開始を宣言するキーワードである。前項の?でスキップされるケースでは，次の}が出現するまでを命令の塊（ブロック）とする。同時にループカウンタとループ先頭ポインタをセットする。ループカウンタは{を実行した直後の内部レジスタの値がmg..4に，ループ先頭ポインタは{の次のアドレスがmg..5に格納される。

条件分岐でブロックを実行対象とするとき，真（0以外）であった内部レジスタの値は論理NOTされて偽（0）となっている。ブロック開始キーワードを実行したとき，ループカウンタには内部レジスタの0がセットされる。0回ループでも1回実行されるが，そのよう仕様になっている理由は，もしかするとここに起因するものなのかもしれない。ともかく，条件分岐を経て実行されているブロックでは，ループカウンタに必ず0が格納されるため，ループがらみでとんでもなく処理が重くなったりすることは避けられているわけだ。

さて，ループカウンタはブロック開始キーワード{の実行のたびにセットされるわけだが，セットされる値はその時点の内部レジスタの値である。{を実行すれば無条件でセットされる。したがって次のようなことも起こりうる。

(式1){ 式1の値の回数繰り返し実行される }
     { 内部レジスタの値の回数繰り返し実行される }

前のブロックの中で内部レジスタの値が変化しなければ，次のブロックも式1の回数分繰り返し実行される。もちろん前のブロックの中で値が評価されて内部レジスタの値が変更されれば，次のブロックまでに内部レジスタが変化しなければ，繰り返し回数はそのままカウンタにセットされる。

        (3){ &m("%d / %d",mg..0,mg..4) (5) }    ;3回繰り返し
        #d#d                                    ;内部レジスタの変化なし
        { &m("%d / %d",mg..0,mg..4) }           ;5回繰り返し

もう気付かれたと思うが，不用意にブロック開始キーワードを書くことは厳に謹まなければならないということになる。内部レジスタの値によっては，それこそ無限にブロック内が実行される危険もあるということだ。

【}】　ブロック終了・ループカウンタのデクリメント

ブロック開始キーワード{と対となるブロック終了キーワードである。実際の動きとしては，}が出現するとループカウンタ（mg..4）を参照して，カウンタの値が0または-1以外ならデクリメントし，その結果のカウンタの値が真（0以外）ならループ先頭ポインタ（mg..5）にジャンプする。

ループでなく条件分岐によって実行されているブロックであっても，実際は０回ループとして実行されている。次のマクロのように内部でループカウンタをセットし直すと，きっちりループすることが確認できるだろう。

        (1)?{ &m("%d / %d / %x",mg..0,mg..4,mg..5 ) (mg..0)??mg..4+=2, }

【>^】　実行中のマクロの先頭にジャンプ

実行中のマクロの先頭にジャンプするキーワードである。直接起動可能なグローバルマクロではオプションやユーザ変数をプッシュしたりする関係もあってあまり使用されず，もっぱらサブルーチン内でのループ様の処理に使用される。

【&+n】　実行中のマクロの+n番のマクロをコール

【&-n】　実行中のマクロの-n番のマクロをコール

【>+n】　実行中のマクロの+n番のマクロにジャンプ

【>-n】　実行中のマクロの-n番のマクロにジャンプ

実行中のマクロの番号にnを加算または減算した番号を付与されているマクロをコールあるいはジャンプするキーワード群である。コール／ジャンプ先マクロはグローバルマクロに限らず，ローカルマクロを含めて最初に見つかったものになる。nの範囲は１桁に納まる数値なので，0〜9。２桁以上の数値を指定しても１文字目だけ認識されるため，分断されて残った数字がコール先から戻った後に単独で実行されることになり，不正なコードになるのでマクロの実行はそこで停止する。

マクロバッファ内を探す順序は，次のようになる。

• 実行中のマクロのあるモジュール内で実行ポインタよりも前方（上位のメモリ位置）に向かって探索
• モジュール内になければマクロバッファの先頭から探索

通常は，モジュール内に見つからなければ，vz.def等のインクルードマクロの番号を探すということになるだろうが，nの範囲を考えると同じモジュールのマクロを指定するための命令と考えておいたほうがよいだろう。

用例：game.def

10:     e-, &01 (t)>?{ >+1 >+2 >+3 >+4 >+5 >+6 >+7 }

１桁制限もあるせいか，使用されている例をあまり目にする機会はない。製品版添付のgame.defは多分にサンプルマクロの様相を示すもので，「こんな命令もあります」的な使い方を示すものであろう。通常はマクロ番号を記述すれば済むことだ。相対番号指定は人間に「数える」必要を生じさせるので，直感的でなく，使い勝手はあまりよいと思えない。

【&*】　最後に組み込んだマクロをコール

【>*】　最後に組み込んだマクロにジャンプ

マクロの組込み関数で最後（直前）に組み込んだマクロをコールあるいはジャンプするキーワードである。もっぱらマクロローダ等の特殊なマクロで使用される。

【>?】　直前の(式)の数値に応じた処理を実行

書式

(式)>?{ 処理0 処理1 処理2 ... }

直前の(式)の数値に対応した処理を実行させる多重分岐である。数値は0から連続するいくつかの範囲に納まることが必要だ。このため式の要素となりうるのは，システムモード(s)，コマンドやメニューの戻り値(r)，日付に対する曜日など整数の剰余(m%n)といったものがほとんどである。

式を評価して内部レジスタに格納された値が0なら処理0を，1なら処理1を，2なら処理2を実行する。0から数えることに注意すること。

処理の内容は，ジャンプ命令や値の受け渡しなど簡易なものでなければならず，複雑な処理をブロック内で行わせることは極力避けるべきである。

用例

        !01                             ;メニューの戻り値を分岐に利用する
        (r<0)?.                         ;キャンセル(r==-1)なら終了
        (r)>?{ >A >B >C >D >E }         ;メニューのアイテム数に応じた処理を用意
 :A     c="リンゴ",                     ;rが0のときの処理
 :B     c="バナナ",                     ;rが1のときの処理
 :C     c="ニンジン",                   ;rが2のときの処理
 :D     c="ドリアン",                   ;rが3のときの処理
 :E     c="エラー：選び直してください", ;rが4のときの処理

用例

        (s)>?{ >A >B >C . . }           ;システムモードで処理を分岐
 :A     p=px, >D
 :B     p=pw, >D
 :C     p=ps, >D
 :D     &?("%s",p)

用例

        (s)>?{ (p=px) (p=pw) (p=ps) . . }       ;システムモードで処理を分岐
        &?("%s",p)

用意した処理の数を超えた値を受け取った場合は，当然のことながらブロックの次の[else]以降を実行することになる。用意した処理をスルーして実行を継続すると不都合を生じることが多々考えられるため，[else]の位置に停止命令やジャンプ命令，例外処理命令などを書いておいた方がよいだろう。

用例

        !01 (r<0)?.
        (r)>?{  }

【>!】　

(式)>!{ c0 op0 c1 op1 | else }

直前の(式)の値に対応した文字に続くブロックを実行し，対応文字がなければ「|」の次に示されたelseを実行する。文字の代わりに(値)を設定することも可能で，コマンドコードの値を渡して分岐することができる。Case文の注意事項も参照のこと。

用例1：vzfl.def

受け取った文字による分岐

        (r)>!{
        @       #Q      ;vzpath
        R       #R      ;rename
        X       >X      ;eXec
        }.
:X      pm="%1 %2", #!

用例2：stkhelp.def by saki...

受け取ったコマンドキーの値による分岐

        ;※rはメニューの戻り値
        (r&$FF+$100)>!{
                (#d)  >S        ; メニュー選択
                ;略

用例3：stkhelp.def by saki...

ポインタで取得した文字の値による分岐

        ;HTML.SHD専用切出しルーチン
        (g..0)>!{
                ('l&') (c="<")
                ('g&') (c=">")
                ('a&') (c="&")
                ;略

用例4：Niflogv.def(delor2.def) by Emmett

「Else」を用いてループ状にしている例

:A      &m("↑: 親発言  ↓: 子発言  ←→: 兄弟発言  [ESC]: Quit")
        &p (r)>!{ (#e) &01 (#s) &02 (#d) &02 (#x) &03 (#[) {&m("")>Z} | >A}

Case文の注意事項

Case文のブロック内では，問題なく使える命令と問題を生じる命令がある。

問題のない命令

• ○ (式)：括弧でくくったもの
• ○ コマンド（#nn）
• ○ 関数のうち引数（括弧でくくったパラメタ）が付かないもの
• ○ コール（&nn：ローカルマクロ）
• ○ ジャンプ（>A:ラベル，>nn:マクロ，>^:マクロ先頭）

問題を生じる命令

• × 式,：実行後{}ブロックの外に出ずにブロック内の次の命令に進んでしまう
• × {ブロック}：次の命令にすり抜けてしまう，３番目以降ではループしてしまう（(式)>? では内部レジスタが残ったままだから）
• × 関数のうち引数（括弧でくくったパラメタ）が付くもの（何番目か数える時に２つ分に数えられてしまう）