一括表示

> 　できれば、メニューで
> 	"C 93/10/10(Sun) 19:34:13"
> 　を先頭に持ってきたいんです。

> !01 (r==-1)?>G (r)>?{>A >B >C >D >E}
　　　　↓　>C の位置を {ブロック} の最初に移動して，
> !01 (r==-1)?>G (r)>?{>C >A >B >D >E}

　　　　↓　C の項目を先頭に移すだけ
> 	"C 93/10/10(Sun) 19:34:13"
> 	"A 15:30:00"
> 	"B 93/10/10 (Sun)"

　５分とかからないでしょう。


> でもメニューで選択すると打鍵数が１つ増えるので、本当は
> この形式のタイムスタンプだけを出力する単独マクロがほしいんですが。
> 年数は４桁全部を出力できるでしょうか？

　さっぱりと短くなって，より簡単ですよ。

= TimeStamp
* m
1 ^\ "タイムスタンプ例"
	(s>1)?.		;編集テキストと入力窓だけ出力を許可
	(mr==$80)?.	;ビューモードでは出力しない
	&s
	ax=$2A00, &i($21)
	&?("%d/%02d/%02d",cx,dx>>8,dx&$ff)
	&?("(%3s)","SunMonTueWedThuFriSat"+(ax&$ff)*3)
;;	(ks&1)?>z	;この行を生かすとシフト起動時は日付だけ出力
	ax=$2C00, &i($21)
	&?(" %02d:%02d:%02d",cx>>8,cx&$ff,dx>>8)
 :z	#?
*

でがらしさん，理屈が解れば面倒はあるものの簡単ですよ。

例えば，先のタイムスタンプマクロを例にすると，

        !01     ;呼び出されたメニューは値を受け取って戻ってくる
        (r<0)?>Z →─────────┐  [ESC]などでキャンセル
        (r)>?{ >A >B >C >D >E }  →─┤  r (メニューの戻り値) に従って分岐
               │ │ │ │ │        │
:A ←─────┘ │ │ │ │        │ r==0 なら ラベル A にジャンプ
｛ 処理1 ｝ >Z → │-│-│-│─┐    │　｛ 処理1 ｝を実行して Z へジャンプ
:B  ←──────┘ │ │ │  │    │ r==1 なら ラベル B にジャンプ
｛ 処理2 ｝ >Z →──│-│-│─┤    │　｛ 処理2 ｝を実行して Z へジャンプ
:C   ←───────┘ │ │  │    │ r==2 なら ラベル C にジャンプ
｛ 処理3 ｝ >Z →─── │-│─┤    │　｛ 処理3 ｝を実行して Z へジャンプ
:D  ←─────────┘ │  │    │ r==3 なら ラベル D にジャンプ
｛ 処理4 ｝ >Z →─────│─┤    │　｛ 処理4 ｝を実行して Z へジャンプ
:E   ←──────────┘  │    │ r==4 なら ラベル E にジャンプ
｛ 処理5 ｝ >Z →───────┤    │　｛ 処理5 ｝を実行して Z へジャンプ
                               │    │
:Z ←─────────────┴──┘
    ;ここに最後の処理を書く
    ;通常はマクロの最初で保存した変数の復帰やサイレントの解除

*P
1 "【メニュー】",33,5
"A 1番目の項目(戻り値=0)"
"B 2番目の項目(戻り値=1)"
"C 3番目の項目(戻り値=2)"
"D 4番目の項目(戻り値=3)"
"E 5番目の項目(戻り値=4)"
*

　…このようになっています。
　メニューの１番目の項目を選択すると戻り値は ０ のようになっていて，
慣れないうちはこれが少し難しく面倒ですが，それさえクリアしてしまえば
もう怖いことはありません。

　なお，メニューの項目の先頭にあるアルファベットは，見易くするための
飾りみたいなものですが，実は先頭の英字は選択用のショートカットキーに
使うことができます。ジャンプ先ラベルとの対応も本来は関係ないのですが，
後々メンテナンスが楽になることは言うまでもありません。

　ぜひ挑戦してみてください。

とりあえず、私が使っているマクロです。
原作者は三浦茂さんです。自分用に、多少の改造は加えてあります。

33 [ESC]T "Time"
        (s>2)?.
        ax=$2A00, &i($21),
        &s
;        w="日月火水木金土"+(ax&$FF)*2,
        w="SunMonTueWedThuFriSat"+(ax&$FF)*3,
        &?("%3s, %02d ",w,dx&$FF)
        w="JanFebMarAprMayJunJulAugSepOctNovDec"+((dx>>8)-1)*3,
        &?("%3s 20%02d",w,cx%100)
        (ks&1)?{&d .}
        ax=$2C00, &i($21),
        &?(" %02d:%02d:%02d +0900 (JST)",cx>>8,cx&$FF,dx>>8)
        &d
        .

表示形式は、ご自分でいじって下さい。
現状は、電子メールでよく使われる形式になっています。