分割位置ワンタッチ変更

作者： 上村　郁夫

　VZの標準機能である[CTRL]+[K][F]（分割位置の変更）では、カーソルキーで境界線を移動して[CR]で確定します。[ESC]でキャンセルできない点はさておき、よく使う分割位置はだいたい決まっているのではないでしょうか。また、元に戻そうとしたものの、真ん中がはっきりわからず、文字どおり割り切れない気分になった人が多いはずです。
　BORDER.DEFを使えば、[CTRL]+[K][F]で「標準位置」と「よく使う位置」がワンタッチで入れ替わります。

横分割（下テキスト拡大）
　（画面７−６）横分割（下テキスト拡大）

縦分割（右テキスト拡大）
　（画面７−７）縦分割（右テキスト拡大）

　わざわざ分割位置を変更するのは、裏テキスト（下または右）をよく見たい場合がほとんどでしょう。表テキストをよく見たければ、[f･4]で全画面に戻せばよいのですから……。裏テキストを小さくして参照することが多い人は、BORDER.DEFにそのための設定が書かれていますので参照してください。
　オマケの機能として、全画面モードで実行すると、ダイレクトに横分割（下テキスト拡大）となります。通常の「分割位置の変更」を実行するには、[CTRL]+[K][SHIFT]+[F]を押してください。

（イラスト）
　２人の子供がケーキを２等分する方法についてもめている。

（キャプション）
　ケーキを仲良く分けるには、
　１人が公平だと思う位置で２つに切り、
　もう１人が好きなほうを選べばよい。
(「Ｖｚマクロコレクション２」所収)
download 
======== border.def ======== by I.Kamimura
* M
80 ^KF  "分割位置のワンタッチ変更"
        ?.
        (ks&1 && wt)? { #65. }          ; シフト実行かつ画面分割なら通常どおり
;       (ks&1 && wt)? { &#Y(0). }       ; シフト実行かつ画面分割なら全画面
        (wt)?? { wh=6, &#Y(2). }        ; 全画面なら横分割（下テキスト拡大）
        t=wt,
        (t&2)? {                        ; 横分割なら
            &s &#Y(0)                   ; いったん全画面に戻す
            (wh==6)? wh=wy/2, ? wh=6,   ; 6:下テキスト拡大
;           (wh==18)? wh=wy/2, ? wh=18, ; 18:上テキスト拡大
            (t&1)? #W &#Y(2) (t&1)? #W
            &d #].
        }
        (t&4)? {                        ; 縦分割なら
            &s &#Y(0)                   ; いったん全画面に戻す
            (wv==10)? wv=wx/2, ? wv=10, ; 10:右テキスト拡大
;           (wv==66)? wv=wx/2, ? wv=66, ; 66:左テキスト拡大
            (t&1)? #W &#Y(4) (t&1)? #W
            &d #].
        }

;*
;======== End of border.def ========